home *** CD-ROM | disk | FTP | other *** search
/ BCI NET / BCI NET Dec 94.iso / archives / programming / source / thesource6.dms / thesource6.adf / Source / Compression / hcompress.lha / hcompress / unix / fcompress.csh < prev    next >
Encoding:
Linux/UNIX/POSIX Shell Script  |  1992-04-21  |  1.8 KB  |  72 lines
  1. #! /bin/csh
  2. # Shell file to do H-transform image compression for a list of image files
  3. # in FITS format.  Files are replaced by <name>.H.
  4. #
  5. # Program will compress only I*2 images with no group parameters.
  6. # (A warning is issued for other images.)
  7. #
  8. # The default compression scale factor is 666, which is appropriate for
  9. # GASP images (gives about a factor of 10 compression, negligible loss in
  10. # information.)
  11. #
  12. # R. White, 20 April 1992
  13. # 
  14. set noclobber
  15. set shellfile=$0
  16. set cdir=`dirname $shellfile`
  17. set prgnam=${shellfile:t}
  18. #
  19. if ($#argv == 0) then
  20.     echo "Usage: ${prgnam} [options] files... [options] files..."
  21.     echo "  where options are:"
  22.     echo "     -s scale to specify the compression scale factor"
  23.     echo "     -k       to keep the uncompressed file (default)"
  24.     echo "     -r       to remove the uncompressed file"
  25.     echo
  26.     echo "Default compression scale factor is 666 (good for GASP images.)"
  27.     echo "Compressed files are named *.*.H."
  28.     exit
  29. endif
  30. set scale=666
  31. set nextscale=0
  32. set remove=0
  33. foreach parm ($*)
  34.     if ($nextscale) then
  35.         set scale=$parm
  36.         set nextscale=0
  37.         echo Using scale $scale
  38.     else
  39.         if ("$parm" == "-s") then
  40.             set nextscale=1
  41.         else if ("$parm" == "-r") then
  42.             set remove=1
  43.         else if ("$parm" == "-k") then
  44.             set remove=0
  45.         else
  46.             set datafile="$parm"
  47.             set compfile="${datafile}.H"
  48.             if (-e $compfile) then
  49.                 echo "${prgnam}: $compfile already exists"
  50.             else if (! -e $datafile) then
  51.                 echo "${prgnam}: ${datafile}: No such file"
  52.             else
  53.                 #
  54.                 # do the compression
  55.                 #
  56.                 echo -n "$datafile "
  57.                 $cdir/hcomp -v -s $scale -i fits $datafile \
  58.                     > $compfile
  59.                 if ($status == 0) then
  60.                   if ($remove) then
  61.                     # delete original file
  62.                     /bin/rm $datafile
  63.                   endif
  64.                 else
  65.                   echo "${prgnam}: $datafile not compressed: compression error"
  66.                   /bin/rm $compfile
  67.                 endif
  68.             endif
  69.         endif
  70.     endif
  71. end
  72.